2015年，在 MATLAB 中创建 DLL 库的过程发生了变化。至于与 MQL5 程序的集成，问题归结为 MATLAB 编译器不再用于创建库，而是面向生成自主可执行文件。自2015年以来，用于创建 DLL 库的函数已转到 MATLAB 编译器SDK。MATLAB 编译器 SDK 扩展了 MATLAB 编译器的功能，允许它从 MATLAB 程序中创建C/C++共享库、Microsoft .NET程序集和Java类。

和以前一样，使用 MATLAB 编译器SDK包中的程序组件创建的应用程序可以在不需要 MATLAB 的用户之间免费重新分发。这些应用程序使用 MATLAB 运行时和一组使用编译应用程序或 MATLAB 组件的共享库。

先前分配给 MATLAB 编译器应用程序的任务已委托给库编译器程序。为了给出完整的流程，让我们探讨从 MATLAB 环境创建C/C++共享库的过程。附加到文章的zip存档包含扩展名为.m的文件，这些文件用于创建库。在 MATLAB 中，启动库编译器应用程序（在 APPS 选项卡上），打开 LibSARIMA.prj 项目，并形成一个类似下图所示的结构。

图 1. 库编译器界面。

在这里，重要的是要注意图1中用线和数字1-4突出显示的位置。 

1. 创建C++标准的共享库
2. ForecastSARIMA.m中显示的函数被导出，而其他函数不受导出的影响，也不被授予访问外部程序的权限。
3. 生成标准接口中用于链接的文件（matlabsarima.dll、matlabsarima.h、matlabsarima.lib）。 
4. mwArray结构上采用了 MATLAB 矩阵访问接口。

按下“打包（Package）”按钮后，将生成库。可以选择要求用户从 Internet 下载 MATLAB 引擎的库生成模式，或者在包内容中包含必要的 MATLAB 引擎组件。 

在此阶段，将创建一个库，其中包含一个用于过滤时间序列、构建 SARIMA 模型和预测的程序。档案 MatlabSArima.zip 提供一组源代码和生成的库构建。

2. 在微软 Visual C++ 中创建中介库

一旦创建了主库，下一个任务就是连接到它，传递数据，并在计算后收集结果。这包括创建一个适配器库，它提供MQL5（用C/C++风格组织的内存）和MATLAB（以矩阵形式组织的内存）之间的数据转换。

要开始为数据编写适配器，需要在操作系统中准备并注册三个系统环境变量。例如，可以通过“系统属性”使用资源管理器，转到“高级系统设置”和“环境变量”。

1. 第一个变量 — MATLAB_2018 应指向装有 MATLAB 或 MATLAB 运行时的目录； 
2. 第二个变量 — MATLAB_2018_LIB64 应指向包含外部库的目录: <MATLAB_2018>\extern\lib\win64;
3. 第三个变量 — MATLIB_USER 应该指向放置原始库的目录。为了解决搜索原始用户库的问题，还必须将此目录添加到系统变量“Path”中。  

为了减少输入股票报价中噪声因素的影响，需要提供额外的过滤和清除错误数据的能力。数据越嘈杂，处理起来就越困难。Kalman 过滤器是一种有效的递归过滤算法，用于各个领域。该算法由预测和调整两个重复阶段组成。首先，计算下一个时间点的状态预测（考虑到测量的不精确性）。然后，考虑到新的信息，对预测值进行校正（同时考虑到该信息的不准确度和噪声）。 

3.2使用 MQL5 的指标程序

指标所需的 adaptersarima.dll 和 matlabsarima.dll 库应放在MetaTrader 5工作目录的 Libraries目录中。

调试和测试有一定的细节。在这种模式下，MetaEditor 从辅助目录中载入库 "<MetaQuotes\Tester\....\Agent-127.0.0.1-300x>", 其中 300x 可以是数值 3000, 3001, 3002, 等等。在这种情况下，将自动复制 AdapterSArima.dll库，但matlabsarima.dll不是。为了防止这影响指标操作，matlabsarima.dll 库应该放在系统搜索目录中。建议将该目录指定为$（MATLIB_USER），并在搜索路径的系统列表中指定该目录，或复制到Windows或Windows\System32。然后将检测到库并连接，指标就将启动。 

根据所考虑的模型实现预测的指标程序可在 ISArimaForecast.mq5 文件和附加的存档中使用。

//+------------------------------------------------------------------+
//|                                              ISArimaForecast.mq5 |
//|                                                Roman Korotchenko |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright   "Roman Korotchenko"
#property link        "https://login.mql5.com/ru/users/Solitonic"
#property description "本指标演示了根据 SARIMA(2,1,2) 来进行预测."
#property description "该程序积极使用MATLAB，具有专业开发的工具箱和扩展能力。"
#property version   "1.00"
#property indicator_chart_window 

#import "AdapterSArima.dll"
int  prepareSARIMA(void);
int  goSarima(double &Res[],double &DataArray[],int idx0,int nLoad,int iSeasonPeriod,int npredict,int filterOn,int PlotOn);
void closeSARIMA(void);
#import

#property indicator_buffers 2    //---- 用于计算和绘制指标的缓冲区
#property indicator_plots   1    //---- 图形构造
#property indicator_type1  DRAW_COLOR_LINE   
#property indicator_color1  clrChocolate, clrBlue // clrWhite, clrBlue
#property indicator_width1  3 
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
enum ENUM_TIMERECALC
  {
   TimeRecalc05 = 5,   // 5 秒
   TimeRecalc10 = 10,  // 10 秒
   TimeRecalc15 = 15,  // 15 秒
   TimeRecalc30 = 30,  // 30 秒
   TimeRecalc60 = 60   // 60 秒
  };
//--- 输入参数
input ENUM_TIMERECALC RefreshPeriod=TimeRecalc30;         // 重计算周期数
input int      SegmentLength  = 450; // N: 数据片段
input int      BackwardShift  = 0;   // 反向偏移 (测试)
input int      ForecastPoints = 25;  // 预测点
input int      SeasonLag=32;         // SARIMA(2,1,2) 的季节延迟
input bool     DoFilter=true;        // 对数据序列做 Kalman 过滤

                                     // input string   _INTERFACE_   = "* INTERFACE *"; 
//input long     magic_numb=19661021777;       // 幻数 

//--- 指标缓冲区
double   DataBuffer[],ColorBuffer[];
//double   LastTrend[],LastData[];

double   wrkResult[],wrkSegment[];
static int wRKLength;

uint CalcCounter;
//
uint calc_data;
uint start_data;    // 构建图表的开始时间
uint now_data;      // 当前时间

static int libReady=0,ErrorHFRange,ErrorDataLength;
static bool   IsCalcFinished;

//+------------------------------------------------------------------+
//| 自定义指标初始化函数                                                 |
//+------------------------------------------------------------------+
static int LengthWithPrediction;

static int PlotOn;
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OnDeinit()
  {
   closeSARIMA();
   Alert("SARIMA DLL - DeInit");
   Print("SARIMA DLL - DeInit");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnInit()
  {
   if(!TerminalInfoInteger(TERMINAL_DLLS_ALLOWED))
      Alert("在终端设置 DLL 中检查连接许可!");
   else
     {
      libReady=prepareSARIMA();
      if(libReady<0)
        {
         Alert("DLL 未能连接!");
         return(INIT_FAILED);
        }

     }

   LengthWithPrediction=SegmentLength+ForecastPoints;
//--- 指标缓冲区映射
   SetIndexBuffer(0,DataBuffer,INDICATOR_DATA);            ArraySetAsSeries(DataBuffer,true);
   SetIndexBuffer(1,ColorBuffer,INDICATOR_COLOR_INDEX);    ArraySetAsSeries(ColorBuffer,true);
// SetIndexBuffer(2,LastTrend,   INDICATOR_CALCULATIONS);   ArraySetAsSeries(LastTrend,true);      //用于 EA
// SetIndexBuffer(3,LastData,    INDICATOR_CALCULATIONS);   ArraySetAsSeries(LastData,true);       //用于EA

   PlotIndexSetInteger(0,PLOT_SHIFT,ForecastPoints-BackwardShift);

   wRKLength = ForecastPoints+ SegmentLength; // 在结果数组中元素的数量
   ArrayResize(wrkResult,wRKLength,0);        // 为函数结果分配内存 memory for function results
   ArrayResize(wrkSegment,SegmentLength,0);   // 为输入数据分配内存

//---   
   string shortname;
   StringConcatenate(shortname,"SARIMA(2,1,2). Season Lag: ",SeasonLag,"  // ");
//--- 用于在数据窗口显示的标签
   PlotIndexSetString(0,PLOT_LABEL,shortname);
   IndicatorSetString(INDICATOR_SHORTNAME,shortname);

   now_data  = 0.001*GetTickCount();
   start_data= 0.001*GetTickCount();
   calc_data = 0;

   CalcCounter    = 1;
   IsCalcFinished = true;

   ErrorHFRange   = 0;
   ErrorDataLength= 0;

   PlotOn=0; // Auxiliary drawing, executed by MATLAB (for testing)

   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| 自定义指标迭代函数                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const int begin,
                const double &price[]
                )
  {
//---
   int ShiftIdx=rates_total-SegmentLength-BackwardShift; // 开始操作数据段的索引

   if(ShiftIdx<0)
     {
      if(!ErrorDataLength)
        {
         PrintFormat("SARIMA 指标错误: 没有足够数据.");
         ErrorDataLength=1;
        }
      return(0);
     }

   ErrorDataLength=0;

//- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 

   now_data=0.001*GetTickCount();

   if(now_data-calc_data<RefreshPeriod || !IsCalcFinished) // 不需要计算或者没有完成
     {
      // ReloadBuffers(prev_calculated,rates_total);
      return(prev_calculated);
     }
   if(prev_calculated!=0 && !IsCalcFinished)
     {
      return(prev_calculated);  // 新数据来的比计算结束更快
     }
//---------------------------------------------------------------------------     

   IsCalcFinished=false; // 阻止请求执行新计算，直到执行当前计算

   int idx=0,iBnd2=ShiftIdx+SegmentLength;
   for(int icnt=ShiftIdx; icnt<iBnd2; icnt++)
     {
      wrkSegment[idx++]=price[icnt];
     }

   ErrorHFRange=0;
// MATLAB SUBROUTINE   
   goSarima(wrkResult,wrkSegment,0,SegmentLength,SeasonLag,ForecastPoints,DoFilter,PlotOn);

   ReloadBuffers(LengthWithPrediction,rates_total);

   ++CalcCounter;
   IsCalcFinished=true; // 准备好进行新的计算

   calc_data=0.001*GetTickCount();

   return(rates_total);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void EmptyBuffers(int n)
  {
   for(int i=0; i<n; i++)
     {
      DataBuffer[i] = EMPTY_VALUE;
      ColorBuffer[i]= EMPTY_VALUE;
     }
  }
//+------------------------------------------------------------------+ 

void ReloadBuffers(int npoint,int ntotal)
  {
   ResetLastError();
   EmptyBuffers(ntotal); // ntotal = rates_total

   if(npoint== 0) return;
   int k=0;//BackwardShift;
   for(int i=0; i<npoint; i++) // npoint = LengthWithPrediction
     {
      if(i>=ntotal) break;
      DataBuffer [k]=wrkResult[LengthWithPrediction-1-i];
      ColorBuffer[k]=(i<ForecastPoints)? 1:0;
      k++;
     }
  }
//=============================================================================

建模结果显示，在前10-12个单元中生成的价格与实时观察到的值匹配的可能性很高。此外，有趣的是，建立模型只需要交易者做一些工作。模型段长度和季节性周期需要两个参数，可通过对最新历史数据进行连续扫描来选择。其余的计算负载转到MATLAB。在未来，可以考虑对分段长度和季节性周期的参数进行优化选择，作为改进指标的一种方法。