• 1. 概述
• 2. 如何计算余额图的趋势线？
• 2.1. 计算优化准则的算法
• 2.2. 引入第一个 TrendProfit 变量
• 2.3. ProfitStability 变量
• 3. 协同 ALGLIB 函数库操作
• 3.1. 计算步骤 (GetProfitStability 方法)
• 4. 包含 CBalanceRegression 类
• 4.1. 利用 MQL5 向导生成智能交易系统
• 4.2. 基于标准 MACD 采样和移动平均线的智能交易系统
• 5. 在 EURUSD H4 上的优化, 未启用前瞻测试
• 5.1. EA test balance regression.mq5, EURUSD H4, 未启用前瞻测试
• 5.1.1测试 1
• 5.1.2. 本地家庭网络中的两台 PC 与云端测试的速度比较
• 5.1.3. 测试 2
• 5.1.4. 测试 3
• 5.2. Moving Average balance regression.mq5, EURUSD H4, 未启用前瞻测试
• 5.2.1. 测试 1 
• 5.2.2. 测试 2
• 5.2.3. 测试 3
• 5.3. MACD Sample balance regression.mq5, EURUSD H4, 未启用前瞻测试
• 5.3.1. 测试 1 
• 5.3.2. 测试 2
• 5.3.3. 测试 3
• 6. EURUSD M15 的优化, 启用前瞻测试
• 6.1. EA test balance regression.mq5, 启用前瞻测试
• 6.1.1. 测试 1
• 6.1.2. 测试 2
• 6.1.3. 测试 3
• 6.2. MACD Sample balance regression.mq5, 启用前瞻测试
• 6.2.1. 测试 1
• 6.2.2. 测试 2
• 6.2.3. 测试 3
• 6.3. Moving Average balance regression.mq5, 启用前瞻测试
• 6.3.1. 测试 1
• 6.3.2. 测试 2
• 6.3.3. 测试 3
• 7 上显示的参数相同。结束语

到目前为止 (统合构建 1645), ALGLIB 函数库已集成到标准库很久了: [数据文件夹]\MQL5\Include\Math\Alglib\alglib.mqh

3.1. 计算步骤 (GetProfitStability 方法)

(佣金 + 掉期 + 利润) > 0.0 的交易结果保存至 arr_profits 数组。所有交易的交易量汇总到 total_volume 变量。

//---
   double   arr_profits[];                            // 成交结果数组 
   double   total_volume=0;                           // 总交易量

接下来, 遍历所有交易 — 填入 arr_profits 数组并累计交易量至 total_volume 变量:

//--- 请求交易历史 
   HistorySelect(m_from_date,to_date);
   uint total_deals=HistoryDealsTotal();
   ulong ticket_history_deal=0;
//--- 对于所有交易 
   for(uint i=0;i<total_deals;i++)
     {
      //--- 尝试得到成交 ticket_history_deal 
      if((ticket_history_deal=HistoryDealGetTicket(i))>0)
        {
         long     deal_type         =HistoryDealGetInteger(ticket_history_deal,DEAL_TYPE);
         double   deal_volume       =HistoryDealGetDouble(ticket_history_deal,DEAL_VOLUME);
         double   deal_commission   =HistoryDealGetDouble(ticket_history_deal,DEAL_COMMISSION);
         double   deal_swap         =HistoryDealGetDouble(ticket_history_deal,DEAL_SWAP);
         double   deal_profit       =HistoryDealGetDouble(ticket_history_deal,DEAL_PROFIT);

         if(deal_type!=DEAL_TYPE_BUY && deal_type!=DEAL_TYPE_SELL)
            continue;

         if(deal_commission==0.0 && deal_swap==0.0 && deal_profit==0.0)
            continue;

         total_volume+=deal_volume;

         int arr_size=ArraySize(arr_profits);
         ArrayResize(arr_profits,arr_size+1,50);   // 调整数组

         if(arr_size==0)
            arr_profits[arr_size]=GetSetStartBalance()+deal_commission+deal_swap+deal_profit;
         else
            arr_profits[arr_size]=arr_profits[arr_size-1]+deal_commission+deal_swap+deal_profit;

         int d=0;
        }
     }

注意: 当我们在 arr_profits 数组里首次加入记录时, 我们 累加初始余额 和交易的清算结果。对于随后的所有记录, 累加前一条记录 和交易的清算结果。

声明 CMatrixDouble 类对象。事实上, 这是一个矩阵。我们来填充: 交易索引 (从 "1" 开始) 的清算结果。

//--- CMatrixDouble 对象
   CMatrixDouble xy(arr_size,2);
   for(int i=0;i<arr_size;i++)
     {
      xy[i].Set(0,i+1);
      xy[i].Set(1,arr_profits[i]);
      //Print(arr_profits[i]); // 用于调试
     }

声明必要的类对象 (CLinReg, CLinearModel, CLRReport) 并计算 线性回归:

//--- 线性回归构造
   CLinReg        linear_regression;
   CLinearModel   linear_model;
   CLRReport      linear_report;
   int retcode;
   linear_regression.LRBuild(xy,arr_size,1,retcode,linear_model,linear_report);
   if(retcode!=1)
     {
      Print("线性回归失败, 错误代码=",retcode);
      return(0.0);
     }
   int nvars;
   double coefficients[];
   linear_regression.LRUnpack(linear_model,coefficients,nvars);
   double coeff_a=coefficients[0];
   double coeff_b=coefficients[1];
   PrintFormat("y = %.1f x + %.1f",coeff_a,coeff_b);

最后, 调用 LRUnpack 方法获取 y = a*x + b 方程的比率。比率位于 coefficients 数组。

现在我们已使用 ALGLIB 函数库计算了线性回归, 我们可以直接计算参数, 这是整篇文章的焦点。

//--- 参数计算
   double TrendProfit=((double)arr_size*coeff_a+coeff_b)-(1.0*coeff_a+coeff_b);  // 回归线在 "Y" 轴上的投影 
   TrendProfit/=(double)arr_size;                                                // 除以交易数量
   double TrendMSE=linear_report.m_rmserror;                                     // 训练集合上的均方根误差
   double ProfitStability=TrendProfit/TrendMSE;
//--- 常规化交易量
   if(GetVolumeNormalization())
      ProfitStability/=total_volume;
//--- 我们乘以交易数量 - 我们对传递少量成交不感兴趣
   ProfitStability*=arr_size;
//---
   return(ProfitStability*10000.0);

根据利用 SetVolumeNormalization 方法设置的初始参数, 我们即可将 ProfitStability 参数除以总的交易量, 也可不除。结果乘以 10000 以便更好地表示结果。

我们来研究包含在 CBalanceRegression 类中可用于各种 EA 的算法。 

4.1. 利用 MQL5 向导生成智能交易系统

我们想检查交易量常规化对结果的影响。这意味着, 我们需要一个能够动态计算已开仓成交量的 EA。这可以在 MQL5 向导 中完成: 选择 智能交易系统 (生成), 并在 "资金管理" 页面中包含一个资金管理模块:

• "固定保证金交易" — 按照可用保证金的 % 计算手数
• "固定风险交易" — 按照余额 % 计算手数
• "优化的成交量交易" — 依照交易历史计算手数

对于本文, 我选择了 "固定风险交易" 的资金管理模块, 而 EA 本身则被命名为 "EA test balance regression.mq5"。以它为例, 我将展示如何包含 CBalanceRegression 类的文件。

步骤 1. 包含 CBalanceRegression 文件并声明类对象 (m_balance_regression)。

//--- 可用的资金管理
#include <Expert\Money\MoneyFixedRisk.mqh>
//--- 可用的余额回归模块
#include <Balance regression\BalanceRegression.mqh>
//+------------------------------------------------------------------+
//| 输入                                                              |
//+------------------------------------------------------------------+

和

//+------------------------------------------------------------------+
//| 智能系统的全局对象                                                  |
//+------------------------------------------------------------------+
CExpert ExtExpert;
CBalanceRegression m_balance_regression;
//+------------------------------------------------------------------+
//| 智能系统的初始化函数                                                 |
//+------------------------------------------------------------------+

步骤 2. 将启用/禁用交易量常规化的参数添加到输入参数:

input double             Money_FixRisk_Percent=10.0;                            // 风险百分比
//--- 余额常规化的输入
input bool               InpVolumeNormalization=true;                           // 交易量常规化
//+------------------------------------------------------------------+
//| 智能系统的全局对象                                                  |
//+------------------------------------------------------------------+

步骤 3. 为 CBalanceRegression 类的 m_balance_regression 对象设置参数: 用于请求交易历史和交易量常规化模式的初始数据:

//+------------------------------------------------------------------+
//| 智能系统的初始化函数                                                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- 设置 CBalanceRegression 的参数
   m_balance_regression.SetStartBalance(AccountInfoDouble(ACCOUNT_BALANCE));
   m_balance_regression.SetFromDate(TimeCurrent());
   m_balance_regression.SetVolumeNormalization(InpVolumeNormalization);
//--- 智能系统初始化

步骤 4. 在文件的末尾添加 OnTester 过程。在此, 我们接收自定义优化标准 (通过调用 GetProfitStability) 并将参数传递给测试器:

//+------------------------------------------------------------------+
//| 测试器函数                                                         |
//+------------------------------------------------------------------+
double OnTester()
  {
//---
   double ret=m_balance_regression.GetProfitStability(TimeCurrent());
//---
   return(ret);
  }

4.2. 智能交易系统基于标准 MACD 采样和 移动平均线

EA 原文件分别位于 [数据文件夹]\MQL5\Experts\Examples\MACD\MACD Sample.mq5 和 [数据文件夹]MQL5\Experts\Examples\Moving Average\Moving Average.mq5 中。

取出原始的 EA, 并以不同的名字保存它们的副本。我已选择好名称 "MACD Sample balance regression.mq5" 和 "Moving Average balance regression.mq5"。

#include <Trade\AccountInfo.mqh>
//--- 可用的余额回归模块
#include <Balance regression\BalanceRegression.mqh>
CBalanceRegression m_balance_regression;
//---
input double InpLots          =0.1; // Lots

#include <Trade\Trade.mqh>
//--- 可用的余额回归模块
#include <Balance regression\BalanceRegression.mqh>
CBalanceRegression m_balance_regression;

input double MaximumRisk        = 0.02;    // 最大风险百分比

input int    InpMATrendPeriod =26;  // MA 趋势周期
//--- 余额常规化的输入
input bool   InpVolumeNormalization=true; // 成交量常规化
//---
int ExtTimeOut=10; // 交易操作之间的超时秒数

input int    MovingShift        = 6;       // 移动均线偏移
//--- 余额常规化的输入
input bool   InpVolumeNormalization=true;  // 成交量常规化
//---
int    ExtHandle=0;

//+------------------------------------------------------------------+
//| 初始化并检查输入参数                                                 |
//+------------------------------------------------------------------+
bool CSampleExpert::Init(void)
  {
//--- 设置 CBalanceRegression 的参数
   m_balance_regression.SetStartBalance(AccountInfoDouble(ACCOUNT_BALANCE));
   m_balance_regression.SetFromDate(TimeCurrent());
   m_balance_regression.SetVolumeNormalization(InpVolumeNormalization);
//--- 初始化公用信息

//+------------------------------------------------------------------+
//| 智能系统初始化函数                                                  |
//+------------------------------------------------------------------+
int OnInit(void)
  {
//--- 设置 CBalanceRegression 的参数
   m_balance_regression.SetStartBalance(AccountInfoDouble(ACCOUNT_BALANCE));
   m_balance_regression.SetFromDate(TimeCurrent());
   m_balance_regression.SetVolumeNormalization(InpVolumeNormalization);
//--- 如果对冲模式激活, 则准备用于控制仓位的交易类

//+------------------------------------------------------------------+
//| 测试器函数                                                         |
//+------------------------------------------------------------------+
double OnTester()
  {
//---
   double ret=m_balance_regression.GetProfitStability(TimeCurrent());
//---
   return(ret);
  }

我们有三个 EA, 在其上我们可以检查使用回归方法优化余额图的思路。两个 EA (EA test balance regression.mq5 和 Moving Average balance regression.mq5) 在交易期间动态计算持仓量, 而 MACD Sample balance regression.mq5 使用固定手数。

5.1. EA test balance regression.mq5, EURUSD H4, 未启用前瞻测试

为了不错过任何选项并加速测试, 我选择了两个参数进行优化 - 开仓/平仓信号的边界参数:

插图7 上显示的参数相同。测试器, 输入选卡

• 测试 1: 优化标准 "余额 + 最大锋锐比率" 参数, 
• 测试 2: 优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'false', 
• 测试 3: 优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'true'。

5.1.1 测试 1: 优化标准 "余额 + 最大锋锐比率" 参数。

针对测试 1 (注: "优化" 等于 "余额 + 最大锋锐比率") 的测试器设置:

插图8. 测试器, 设置选卡

5.1.2. 本地家庭网络中的两台 PC 与云端测试的速度比较

家庭网络内拥有两台电脑:

1. 一台笔记本配置为四核 Intel Core i3-3120M @2.50GHz, 8077 MB。由于终端还需要与第二台计算机上的代理进行通信, 因此测试中只使用了四个代理中的三个。
2. 一台桌面机配置为六核 AMD Phenom II X6 1075T 处理器, 4058 MB。测试中只使用六个代理中的四个代理, 以免 CPU 过热。

插图9. 家庭网络中的优化

测试 1 在 家庭网络中 21 分 43 秒内通关。

现在, 我删除缓存内的测试结果, 并在 MQL5 Cloud Europe 1 上启动测试 1。在 云端, 测试花费了 1 分 9 秒。测试成本为 $0.06。

测试 1 结果, 结果列按降序排列, 五个最佳结果:

插图10. 测试 1, 优化通关 346

5.1.3. 测试 2: 优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'false'。

针对测试 2 (注: "优化" 等于 "自定义最大") 的测试器设置:

插图11. 测试器, 设置选卡

 针对测试 2 (注: "交易量常规化" 在 Value 栏为 'false') 的测试器设置:

插图12. 测试器, 输入选卡

测试 2 结果, 结果列按降序排列, 五个最佳结果:

插图13. EURUSDH4, 测试 2, 优化通关 270

5.1.4. 测试 3: 优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'true':

针对测试 3 (设置与测试 2 类似) 的测试器设置:

插图14. 测试器, 设置选卡

针对测试 3 (注: "交易量常规化" 在 Value 栏为 'true') 的测试器设置:

插图15. 测试器, 输入选卡

在云端, 测试花费 2 分 27 秒。整个测试在 MQL5 Cloud Europe 1 上进行。测试成本是 $0.08。

测试 3 结果, 结果列按降序排列, 五个最佳结果:

5.2. Moving Average balance regression.mq5, EURUSD, H4, 未启用前瞻测试

选择以下参数用于优化:

插图16. 测试器, 输入选卡

我将针对 Moving Average balance regression EA 进行三次测试:

• 测试 1: 优化标准 "余额 + 最大锋锐比率" 参数, 
• 测试 2: 优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'false', 
• 测试 3: 优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'true'。

测试器设置 (货币, 逐笔报价的生成方法和时间间隔与插图 5 相同)。

5.2.1. 测试 1 (优化标准 "余额 + 最大锋锐比率" 参数) 在云端执行。在云端, 测试花费 1 分 22 秒。整个测试在 MQL5 Cloud Europe 1 上进行。测试成本为 $0.03。

测试 1 结果, 结果列按降序排列, 五个最佳结果:

我们来看看最佳通关 #19:

插图17. EURUSDH4, 测试 1, 优化通关 19

5.2.2. 测试 2 (优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'false') 在云端执行。在云端, 测试花费 0 分 00 秒, 因为结果已经从缓存中获取, 尽管它们是逆反的。整个测试在 MQL5 Cloud Europe 2 上进行。测试成本为 $0.00。

测试 2 结果, 结果列按降序排列, 五个最佳结果:

通关 141 位于表格的最顶端 (它在结果列中具有最大值):

插图18. EURUSDH4, 测试 2, 优化通关 141

5.2.3. 测试 3 (优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'true') 在云端执行。在云端, 测试花费 1 分 13 秒。整个测试在 MQL5 Cloud Europe 2 上进行。测试成本为 $0.05。

测试 3 结果, 结果列按降序排列, 五个最佳结果:

测试器设置 (货币, 逐笔报价的生成方法和时间间隔与插图5 相同)。

5.3.1. 测试 1 (优化标准 "余额 + 最大锋锐比率" 参数) 在云端执行。在云端, 测试花费 3 分 55 秒 (时间相比较大, 由于任务没有在一些慢速代理上执行, 所以, 10 个任务分布在其它代理上)。整个测试在 MQL5 Cloud Europe 1 上进行。测试成本为 $0.04。

测试 1 结果:

在这个时间帧内, 很少有交易 (从 13 日到 16 日)。我希望在较低的时间帧内会有更多的交易 (M15)。这些测试在下面的另一章节中显示。而现在, 最佳结果是 #163:

插图20. EURUSDH4, 测试 1, 优化通关 163

5.3.2. 测试 2 (优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'false') 在云端执行。在云端, 测试花费 0 分 00 秒, 因为结果已经从缓存中获取, 尽管它们是逆反的。整个测试在 MQL5 Cloud Europe 2 上进行。测试成本为 $0.00。

测试 2 结果:

5.3.3. 测试 3 (优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'true') 在云端执行。在云端, 测试花费 1 分 5 秒。整个测试在 MQL5 Cloud Europe 2 上进行。测试成本为 $0.05。

测试 3 结果:

我们有相同的三个 EA: EA test balance regression.mq5, Moving Average balance regression.mq5 和 MACD Sample balance regression.mq5。与以前的测试不同, 我们现在启用 前瞻测试, 并在 M15 上测试。

6.1. EA test balance regression.mq5, 前瞻测试。我将进行 三次测试:

• 测试 1: 优化标准 "余额 + 最大锋锐比率" 参数
  
• 测试 2: 优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'false'
  
• 测试 3: 优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'true'。

6.1.1. 测试 1: 优化标准 "余额 + 最大锋锐比率" 参数。测试器设置:

插图21. 测试器, 设置选卡

测试器参数与插图 7 上显示的参数相同。

在云端, 测试花费 2 分 14 秒。整个测试在 MQL5 Cloud Europe 2 上进行。测试成本是 $0.08。

优化结果:

插图22. EURUSDM15, 测试 1, 优化通关 352

前瞻结果:

在此, 最好的选项是在前瞻区域只有 10 笔交易的那个。当然, 这还不够, 但我们仍然需要进行测试:

插图23。EURUSDM15, 测试 1, 前瞻通关 284

6.1.2. 测试 2: 优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'false'。

最佳优化结果 (非前瞻):

插图24. EURUSDM15, 测试 2, 优化通关 284

前瞻结果:

6.1.3. 测试 3: 优化 "自定义最大" 自定义参数, 而已交易量优化参数是 'true'。在云端, 测试花费 3 分 29 秒。整个测试在 MQL5 Cloud Europe 1 上进行。测试成本为 $0.07。

最佳优化结果 (非前瞻):

插图25. EURUSDM15, 测试 3, 优化通关 208

启用 "交易量常规化" 对结果没有显著影响。而且, 在优化间隔内发现了最佳结果之一。

最好的前瞻结果:

6.2. MACD Sample balance regression.mq5, 前瞻测试

6.2.1. 测试 1: 优化标准 "余额 + 最大锋锐比率" 参数, 在云端执行。在云端, 测试花费 1 分 3 秒。整个测试在 MQL5 Cloud Europe 1 上进行。测试成本为 $0.06。

优化结果:

插图26. EURUSDM15, 测试 1, 优化通关 171

运用线性回归方法优化余额图的结果已经证明达至 "余额 + 最大锋锐比率" 优化方法的水平。使用动态手数的 EA 显示出有趣的结果: 在某些情况下, "交易量常规化" 设置与前瞻测试相结合产生更可靠的画面。

我相信, 所描述的方法有权存在, 且可进一步改进, 例如考虑盈利和亏损交易的持续时间, 并对所得到的数值进行实验。