然后我们总结出匹配值和反演值，它们的差等于 -37。通过将该值插入公式中，我们得到 Kendall 系数等于 -0,82。这又是一个很强的负相关。然而，结果表明，该方法比前两种方法更具选择性，因为绝对值较小。

如你所见，Fechner 相关系数的计算方法相当简单。结果值为 -0,8. 这再次表明，收盘价与烛形编号之间存在着强烈的负相关关系。

指标的实现

现在，让我们使用MQL5语言实现所有相关计算方法。 

Pearson 相关系数

由于 Pearson 系数是用大公式计算的，所以计算分为两个阶段：分子和分母的计算。

//+------------------------------------------------------------------+
//| 分子的计算                                                         |
//+------------------------------------------------------------------+
double Numerator(double &Ranks[],int N)
  {
//----
   double Y[],dx[],dy[],mx=0.0,my=0.0,sum=0.0,sm=0.0;
   ArrayResize(Y,N);
   ArrayResize(dx,N);
   ArrayResize(dy,N);

   int n=N;
   for(int i=0; i<N; i++)
     {
      Y[i]=n;
      n--;
     }

   mx=Average(Y);
   my=Average(Ranks);

   for(int j=0;j<N;j++)
     {
      dx[j]=Y[j]-mx;
      dy[j]=Ranks[j]-my;
      sm+=dx[j]*dy[j];
     }
   return sm;
  }
//+------------------------------------------------------------------+
//| 分母的计算                                                         |
//+------------------------------------------------------------------+
double Denominator(double &Ranks[],int N)
  {
//----
   double Y[],dx2[],dy2[],mx=0.0,my=0.0,sum=0.0,smx2=0.0,smy2=0.0;
   ArrayResize(Y,N);
   ArrayResize(dx2,N);
   ArrayResize(dy2,N);

   int n=N;
   for(int i=0; i<N; i++)
     {
      Y[i]=n;
      n--;
     }

   mx=Average(Y);
   my=Average(Ranks);

   for(int j=0;j<N;j++)
     {
      dx2[j]=MathPow(Y[j]-mx,2);
      dy2[j]=MathPow(Ranks[j]-my,2);
      smx2+=dx2[j];
      smy2+=dy2[j];
     }
   return(MathSqrt(smx2*smy2));
  }

指标可视化的最终计算方法和计算逻辑如下：

//+------------------------------------------------------------------+
//| 自定义指标迭代函数                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,    // 当前分时历史中的柱数
                const int prev_calculated,// 前一次调用时计算的柱数
                const int begin,          // 柱开始计数的索引
                const double &price[]
                )

  {
   if(rates_total<rangeN+begin)
      return(0);
   int limit;

   if(prev_calculated>rates_total || prev_calculated<=0)
     {
      limit=rates_total-2-rangeN-begin;
      if(begin>0)
         PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,rangeN+begin);
     }
   else
      limit=rates_total-prev_calculated;

   ArraySetAsSeries(price,true);

   for(int i=0; i<=limit; i++)
     {
      for(int k=0; k<rangeN; k++)
         PriceInt[k]=price[k+i];
      ExtLineBuffer[i]=PearsonCalc(PriceInt,rangeN);
     }

   return(rates_total);
  }

//+------------------------------------------------------------------+
//| 计算 Pearson 相关系数                                              |
//+------------------------------------------------------------------+
double PearsonCalc(double &Ranks[],int N)
  {
   double ch,zn;
   ch=Numerator(Ranks,N);
   zn=Denominator(Ranks,N);
   return (ch/zn);
  }

Spearman 等级相关系数

//+------------------------------------------------------------------+
//| 自定义指标迭代函数                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,    // 当前分时历史中的柱数
                const int prev_calculated,// 前一次调用时计算的柱数
                const int begin,          // 柱开始计数的索引
                const double &price[]
                )

  {
   if(rates_total<rangeN+begin)
      return(0);
   int limit;

   if(prev_calculated>rates_total || prev_calculated<=0)
     {
      limit=rates_total-2-rangeN-begin;
      if(begin>0)
         PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,rangeN+begin);
     }
   else
      limit=rates_total-prev_calculated;

   ArraySetAsSeries(price,true);

   for(int i=limit; i>=0; i--)
     {
      for(int k=0; k<rangeN; k++)
         PriceInt[k]=int(price[i+k]*multiply);

      RankPrices(TrueRanks,PriceInt);
      ExtLineBuffer[i]=SpearmanCalc(R2,rangeN);
     }

   return(rates_total);
  }
//+------------------------------------------------------------------+
//| 计算 Spearman 相关系数                                             |
//+------------------------------------------------------------------+
double SpearmanCalc(double &Ranks[],int N)
  {
//----
   double sumd2=0.0;

   for(int i=0; i<N; i++)
      sumd2+=MathPow(Ranks[i]-i-1,2);

   return(1-6*sumd2/(N*(MathPow(N,2)-1)));
  }

//+------------------------------------------------------------------+
//| 自定义指标迭代函数                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,    // 当前分时历史中的柱数
                const int prev_calculated,// 前一次调用时计算的柱数
                const int begin,          // 柱开始计数的索引
                const double &price[]
                )

  {
   if(rates_total<rangeN+begin)
      return(0);
   int limit;

   if(prev_calculated>rates_total || prev_calculated<=0)
     {
      limit=rates_total-2-rangeN-begin;

      if(begin>0)
         PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,rangeN+begin);
     }
   else
      limit=rates_total-prev_calculated;

   ArraySetAsSeries(price,true);

   for(int i=0; i<=limit; i++)
     {
      for(int k=0; k<rangeN; k++)
         PriceInt[k]=price[k+i];
      ExtLineBuffer[i]=KendallCalc(PriceInt,rangeN);
     }

   return(rates_total);
  }
//+------------------------------------------------------------------+
//| 计算 Kendall 相关系数                                              |
//+------------------------------------------------------------------+
double KendallCalc(double &Ranks[],int N)
  {
   double Y[],t;
   ArrayResize(Y,N);

   int n=N;
   for(int i=0; i<N; i++)
     {
      Y[i]=n;
      n--;
     }
   MathCorrelationKendall(Ranks,Y,t);
   return (t);
  }
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+
//| 自定义指标迭代函数                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,    // 当前分时历史中的柱数
                const int prev_calculated,// 前一次调用时计算的柱数
                const int begin,          // 柱开始计数的索引
                const double &price[]
                )

  {
   if(rates_total<rangeN+begin)
      return(0);
   int limit;

   if(prev_calculated>rates_total || prev_calculated<=0)
     {
      limit=rates_total-2-rangeN-begin;
      if(begin>0)
         PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,rangeN+begin);
     }
   else
      limit=rates_total-prev_calculated;

   ArraySetAsSeries(price,true);
   for(int i=0; i<=limit; i++)
     {
      for(int k=0; k<rangeN; k++)
         PriceInt[k]=price[k+i];
      ExtLineBuffer[i]=FechnerCalc(PriceInt,rangeN);
     }

   return(rates_total);
  }
//+------------------------------------------------------------------+
//| 计算 Fechner 相关系数                                              |
//+------------------------------------------------------------------+
double FechnerCalc(double &Ranks[],int N)
  {
   double Y[],res,mx,my,sum=0.0,markx[],marky[];
   double Na=0.0,Nb=0.0;
   ArrayResize(Y,N);
   ArrayResize(markx,N);
   ArrayResize(marky,N);

   int n=N;
   for(int i=0; i<N; i++)
     {
      Y[i]=n;
      n--;
     }

   mx=Average(Y);
   my=Average(Ranks);

   for(int j=0; j<N; j++)
     {
      markx[j]=(Y[j]>mx)?1:-1;
      marky[j]=(Ranks[j]>my)?1:-1;
      if(markx[j]==marky[j])
         Na++;
      else
         Nb++;
     }

   res=(Na-Nb)/(Na+Nb);
   return (res);
  }

图7 交易相关系数的下降。

从截图中可以看出，有两个对称的相关系数水平：卖出水平0.3和买入水平0.3。当卖出水平向下被突破时，开启卖出订单。当买入水平被向上突破时，开启买入订单。

图8 交易相关系数的增长。  

在图8所示的第二种交易模式中，关键的市场进入水平是相反的。这一次，当买入水平向上被突破时，开启一个买入订单。当卖出水平被向下突破时，开启一个卖出订单。 

为了实现 EA 交易，我们需要提供上述策略，并选择适当的相关计算方法。

//+------------------------------------------------------------------+
//| 运行模式的枚举                                                      |
//+------------------------------------------------------------------+
enum Strategy_type
  {
   DECREASE = 1,           //On Decrease       
   INCREASE                //On Increase
  };
//+------------------------------------------------------------------+
//| 相关性计算方法的枚举                                                 |
//+------------------------------------------------------------------+
enum Corr_method
  {
   PEARSON = 1,            //Pearson       
   SPEARMAN,               //Spearman
   KENDALL,                //Kendall
   FECHNER                 //Fechner
  };

除了EA参数外，我们还要添加以下输入：计算方法的选择、策略、关键水平和可调整的操作时间框架。

//+------------------------------------------------------------------+
//| EA 交易输入参数                                                    |
//+------------------------------------------------------------------+
input    string               Inp_EaComment="Correlation Strategy";        //EA 注释
input    double               Inp_Lot=0.01;                                //手数
input    MarginMode           Inp_MMode=LOT;                               //资金管理

//--- 相关性的计算
input    Corr_method          Inp_Corr_method=1;                           //相关性方法
input    Strategy_type        Inp_Strategy_type=1;                         //策略类型

//--- EA 参数
input    string               Inp_Str_label="===EA parameters===";         //标签
input    int                  Inp_MagicNum=1111;                           //幻数
input    int                  Inp_StopLoss=40;                             //止损(点数)
input    int                  Inp_TakeProfit=60;                           //获利(点数)
//--- 指标参数 
input    int                  Inp_RangeN=10;                               //范围计算
input    double               Inp_KeyLevel=0.2;                            //关键水平    
input    ENUM_TIMEFRAMES      Inp_Timeframe=PERIOD_CURRENT;                //工作时间框架

在EA初始化步骤中将检查关键水平的正确性：水平必须位于0和1之间，因为水平将使用绝对值。

//--- 检查关键水平的正确性
   if(Inp_KeyLevel>1 || Inp_KeyLevel<0)
     {
      Print(Inp_EaComment,": 错误的关键水平!");
      return(INIT_FAILED);
     }

然后设置输入参数中选择的相关计算方法：

//--- 
   switch(Inp_Corr_method)
     {
      case 1:
         ind_type="Correlation\\PearsonCorrelation";
         break;
      case 2:
         ind_type="Correlation\\SpearmanCorrelation";
         break;
      case 3:
         ind_type="Correlation\\KendallCorrelation";
         break;
      case 4:
         ind_type="Correlation\\FechnerCorrelation";
         break;
      default:
         break;
     }
//--- 取得指标句柄 
   InpInd_Handle=iCustom(Symbol(),Inp_Timeframe,ind_type,Inp_RangeN);
   if(InpInd_Handle==INVALID_HANDLE)
     {
      Print(Inp_EaComment,": Failed to get indicator handle");
      Print("Handle = ",InpInd_Handle,"  error = ",GetLastError());
      return(INIT_FAILED);
     }

之后，我们可以设置进场条件和EA操作逻辑。

//+------------------------------------------------------------------+
//| EA交易分时函数                                                     |
//+------------------------------------------------------------------+
void OnTick()
  {
//--- 取得用于计算的数据

   if(!GetIndValue())
      return;

   if(!Trade.IsOpenedByMagic(Inp_MagicNum))
     {
      //--- 如果有买入信号，开启订单
      if(BuySignal())
         Trade.BuyPositionOpen(Symbol(),Inp_Lot,Inp_StopLoss,Inp_TakeProfit,Inp_MagicNum,Inp_EaComment);
      //--- 如果有卖出信号，开启订单
      if(SellSignal())
         Trade.SellPositionOpen(Symbol(),Inp_Lot,Inp_StopLoss,Inp_TakeProfit,Inp_MagicNum,Inp_EaComment);
     }
  }
//+------------------------------------------------------------------+
//| 买入条件                                                           |
//+------------------------------------------------------------------+
bool BuySignal()
  {
   bool res=false;
   if(Inp_Strategy_type==1)
      res=(corr[1]>Inp_KeyLevel && corr[0]<Inp_KeyLevel)?true:false;
   else if(Inp_Strategy_type==2)
      res=(corr[0]>Inp_KeyLevel && corr[1]<Inp_KeyLevel)?true:false;
   return res;
  }
//+------------------------------------------------------------------+
//| 卖出条件                                                          |
//+------------------------------------------------------------------+
bool SellSignal()
  {
   bool res=false;
   if(Inp_Strategy_type==1)
      res=(corr[1]<-Inp_KeyLevel && corr[0]>-Inp_KeyLevel)?true:false;
   else if(Inp_Strategy_type==2)
      res=(corr[0]<-Inp_KeyLevel && corr[1]>-Inp_KeyLevel)?true:false;
   return res;
  }

测试

EA 交易将使用以下参数进行测试:

• 时间段: 对于上涨趋势模式01.01.2015 — 01.12.2018.
• 货币对: EURUSD.
• 交易模式: 无延迟. 这些都不是高频交易策略，因此延迟的影响将非常小。
  
• 测试: M1 OHLC. 在真实分时上的预测试显示几乎同样的结果。 
  
• 初始存款: 1000 USD.
• 杠杆: 1:500.
• 服务器: MetaQuotes-Demo.
• 报价: 5-digit.

测试和优化参数.

图9 需要优化的参数集。

优化将有助于确定哪种计算方法和策略类型更可取。测试和优化产生了以下结果。

图10 测试和优化结果。

现在让我们使用最佳优参数测试EA。

图11 最佳参数测试结果。

研究结果

根据所得结果，可进行以下观察：

• 采用相关系数下降策略，在 On Decrease 模式下，得到了最佳结果。这一结果只能解释为当系数下降时，振荡指标对市场波动的反应更快如上所述，基于相关系数的振荡指标（尤其是那些周期较大的振荡指标）具有显著的滞后性。
• 在前20个结果中没有找到最简单的计算方法（Fechner 系数），此方法的最佳结果仅位于第99位。 
• 在短时间内取得了最好的结果，取得了很好的盈利和止损效果。
• 未找到所选期间和关键级别的利润额依赖关系。然而，以较小的周期为准，在最佳结果中经常遇到周期为5的优化范围下限。这是另一个证明，基于相关性的指标在大周期内有较大的延迟，并且结果较差。

附加的存档包含所有列出的文件，这些文件位于相应的文件夹中。为了使它们正确工作，您只需要把它们保存到终端文件夹的 MQL5 文件夹下。

文章中使用的程序